Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
_acpi	1.24 KB	-rw-r--r--
_acpitool	2.38 KB	-rw-r--r--
_alsa-utils	2.69 KB	-rw-r--r--
_analyseplugin	647 B	-rw-r--r--
_brctl	1.88 KB	-rw-r--r--
_btrfs	18.96 KB	-rw-r--r--
_chattr	1019 B	-rw-r--r--
_chcon	1.35 KB	-rw-r--r--
_chrt	2.5 KB	-rw-r--r--
_cpupower	4.12 KB	-rw-r--r--
_cryptsetup	8.22 KB	-rw-r--r--
_dkms	5.29 KB	-rw-r--r--
_e2label	93 B	-rw-r--r--
_ethtool	11.72 KB	-rw-r--r--
_findmnt	5.09 KB	-rw-r--r--
_free	1.25 KB	-rw-r--r--
_fuse_arguments	1.05 KB	-rw-r--r--
_fuse_values	1.61 KB	-rw-r--r--
_fusermount	660 B	-rw-r--r--
_gpasswd	701 B	-rw-r--r--
_htop	640 B	-rw-r--r--
_iconvconfig	508 B	-rw-r--r--
_ionice	1.14 KB	-rw-r--r--
_ipset	6.04 KB	-rw-r--r--
_iptables	10.43 KB	-rw-r--r--
_iwconfig	2.34 KB	-rw-r--r--
_kpartx	488 B	-rw-r--r--
_losetup	2.14 KB	-rw-r--r--
_lsattr	335 B	-rw-r--r--
_lsblk	3.01 KB	-rw-r--r--
_lsusb	1.16 KB	-rw-r--r--
_ltrace	2.15 KB	-rw-r--r--
_mdadm	8.02 KB	-rw-r--r--
_mii-tool	856 B	-rw-r--r--
_modutils	5.93 KB	-rw-r--r--
_mondo	1.95 KB	-rw-r--r--
_networkmanager	9.41 KB	-rw-r--r--
_opkg	15.12 KB	-rw-r--r--
_pidof	924 B	-rw-r--r--
_pkgtool	2.38 KB	-rw-r--r--
_pmap	1.02 KB	-rw-r--r--
_qdbus	2.68 KB	-rw-r--r--
_schedtool	916 B	-rw-r--r--
_selinux_contexts	266 B	-rw-r--r--
_selinux_roles	184 B	-rw-r--r--
_selinux_types	184 B	-rw-r--r--
_selinux_users	274 B	-rw-r--r--
_setsid	387 B	-rw-r--r--
_slabtop	674 B	-rw-r--r--
_ss	4.97 KB	-rw-r--r--
_sshfs	2.48 KB	-rw-r--r--
_strace	6.75 KB	-rw-r--r--
_sysstat	7.22 KB	-rw-r--r--
_tload	370 B	-rw-r--r--
_tpb	975 B	-rw-r--r--
_tracepath	320 B	-rw-r--r--
_tune2fs	2.19 KB	-rw-r--r--
_uml	5.14 KB	-rw-r--r--
_valgrind	15.33 KB	-rw-r--r--
_vserver	2.93 KB	-rw-r--r--
_wakeup_capable_devices	439 B	-rw-r--r--
_wipefs	1.3 KB	-rw-r--r--
_wpa_cli	825 B	-rw-r--r--

Code Editor : _lsblk

#compdef lsblk

local sep ret=1
local -a values dedup suf
local curcontext="$curcontext" state line expl
typeset -A opt_args

_arguments -C -s -S \
  '(H -E --dedup)'{-E+,--dedup=}'[de-duplicate output by specified column]:column:->columns' \
  '(H -a --all)'{-a,--all}'[print all devices]' \
  '(H -b --bytes)'{-b,--bytes}'[print size in bytes rather than in human readable format]' \
  '(H -d --nodeps)'{-d,--nodeps}"[don't print slaves or holders]" \
  '(H -I --include)*'{-e,--exclude}'[exclude devices by major number]:major device number:->majorlist' \
  '(H -e --exclude)*'{-I+,--include=}'[show only devices with specified major numbers]:major device number:->majorlist' \
  '(H -n --noheadings)'{-n,--noheadings}"[don't print headings]" \
  '(H -p --paths)'{-p,--paths}'[print complete device path]' \
  '(H -s --inverse)'{-s,--inverse}'[reverse dependency order]' \
  '(H -x --sort)'{-x+,--sort=}'[sort output by specified column]:column:->columns' \
  '(H)--sysroot=[use specified directory as system root]:directory:_directories' \
  '*:device:_files -g "*(-%b)" -P / -W /' \
  + fields \
  '(H -D --discard -o --output -O --output-all)'{-D,--discard}'[output discard capabilities]' \
  '(H -z --zoned -o --output -O --output-all)'{-z,--zoned}'[output zone model]' \
  '(H -f --fs -o --output -O --output-all)'{-f,--fs}'[output info about filesystems]' \
  '(H -m --perms -o --output -O --output-all)'{-m,--perms}'[output info about permissions]' \
  '(H -S --scsi -o --output -O --output-all)'{-S,--scsi}'[output info about SCSI devices]' \
  '(H -t --topology -o --output -O --output-all)'{-t,--topology}'[output info about topology]' \
  '(H fields)'{-o+,--output=}'[specify output columns]:output column:->columnlist' \
  '(H fields)'{-O,--output-all}'[output all columns]' \
  + '(format)' \
  '(H)'{-i,--ascii}'[output ascii characters only]' \
  '(H)'{-J,--json}'[use JSON output format]' \
  '(H)'{-l,--list}'[use list format output]' \
  '(H)'{-T+,--tree=}'[use tree format output]:column:->columns' \
  '(H)'{-P,--pairs}'[use key="value" output format]' \
  '(H)'{-r,--raw}'[use raw output format]' \
  + 'H' \
  '(* -)'{-h,--help}'[display help information]' \
  '(* -)'{-V,--version}'[display version information]' && ret=0

case $state in
  columnlist)
    compset -P '+' || _describe -t list-prefixes prefix \
		      '( +:"not replace but extend the list" )' -S '' && ret=0
  ;|
  *list)
    dedup=( ${(Ms.,.)PREFIX##*,} ${(Ms.,.)SUFFIX%%,*} )
    suf=( -qS , )
    compset -S ',*' && suf=()
    compset -P '*,'
  ;|
  column*)
    values=(
      ${${${${(f)"$(_call_program columns lsblk -h)"}[(r)Available*,-2]## #}[2,-1]//:/\\:}/  /:}
    )
    _describe -t fields column values -M 'm:{a-z}={A-Z}' $suf -F dedup && ret=0
  ;;
  major*)
    zstyle -s ":completion:${curcontext}:" list-separator sep || sep=--
    values=( ${${${(f)"$(</proc/devices)"}[(r)Block*,-1]## #}[2,-1]/ /:} )
    zformat -a values " $sep " $values
    _wanted -V devices expl 'major device number' compadd $suf -d values -F dedup ${values%% *} && ret=0
  ;;
esac

return ret

${this.title}

Code Editor : _lsblk