Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
_acpi	1.24 KB	-rw-r--r--
_acpitool	2.38 KB	-rw-r--r--
_alsa-utils	2.69 KB	-rw-r--r--
_analyseplugin	647 B	-rw-r--r--
_brctl	1.88 KB	-rw-r--r--
_btrfs	18.96 KB	-rw-r--r--
_chattr	1019 B	-rw-r--r--
_chcon	1.35 KB	-rw-r--r--
_chrt	2.5 KB	-rw-r--r--
_cpupower	4.12 KB	-rw-r--r--
_cryptsetup	8.22 KB	-rw-r--r--
_dkms	5.29 KB	-rw-r--r--
_e2label	93 B	-rw-r--r--
_ethtool	11.72 KB	-rw-r--r--
_findmnt	5.09 KB	-rw-r--r--
_free	1.25 KB	-rw-r--r--
_fuse_arguments	1.05 KB	-rw-r--r--
_fuse_values	1.61 KB	-rw-r--r--
_fusermount	660 B	-rw-r--r--
_gpasswd	701 B	-rw-r--r--
_htop	640 B	-rw-r--r--
_iconvconfig	508 B	-rw-r--r--
_ionice	1.14 KB	-rw-r--r--
_ipset	6.04 KB	-rw-r--r--
_iptables	10.43 KB	-rw-r--r--
_iwconfig	2.34 KB	-rw-r--r--
_kpartx	488 B	-rw-r--r--
_losetup	2.14 KB	-rw-r--r--
_lsattr	335 B	-rw-r--r--
_lsblk	3.01 KB	-rw-r--r--
_lsusb	1.16 KB	-rw-r--r--
_ltrace	2.15 KB	-rw-r--r--
_mdadm	8.02 KB	-rw-r--r--
_mii-tool	856 B	-rw-r--r--
_modutils	5.93 KB	-rw-r--r--
_mondo	1.95 KB	-rw-r--r--
_networkmanager	9.41 KB	-rw-r--r--
_opkg	15.12 KB	-rw-r--r--
_pidof	924 B	-rw-r--r--
_pkgtool	2.38 KB	-rw-r--r--
_pmap	1.02 KB	-rw-r--r--
_qdbus	2.68 KB	-rw-r--r--
_schedtool	916 B	-rw-r--r--
_selinux_contexts	266 B	-rw-r--r--
_selinux_roles	184 B	-rw-r--r--
_selinux_types	184 B	-rw-r--r--
_selinux_users	274 B	-rw-r--r--
_setsid	387 B	-rw-r--r--
_slabtop	674 B	-rw-r--r--
_ss	4.97 KB	-rw-r--r--
_sshfs	2.48 KB	-rw-r--r--
_strace	6.75 KB	-rw-r--r--
_sysstat	7.22 KB	-rw-r--r--
_tload	370 B	-rw-r--r--
_tpb	975 B	-rw-r--r--
_tracepath	320 B	-rw-r--r--
_tune2fs	2.19 KB	-rw-r--r--
_uml	5.14 KB	-rw-r--r--
_valgrind	15.33 KB	-rw-r--r--
_vserver	2.93 KB	-rw-r--r--
_wakeup_capable_devices	439 B	-rw-r--r--
_wipefs	1.3 KB	-rw-r--r--
_wpa_cli	825 B	-rw-r--r--

Code Editor : _cpupower

#compdef cpupower

local curcontext="$curcontext" ret=1
local -a state line expl cmds args
typeset -A opt_args

_arguments -C \
  '(- :)'{-h,--help}'[print help information]' \
  '(- :)'{-v,--version}'[print version information]' \
  '(-d --debug)'{-d,--debug}'[enable debug output]' \
  '(-c --cpu)'{-c,--cpu}'[limit values to specific processor cores]:cpu' \
  ':cmd:->cmds' \
  '*::arg:->args' && ret=0

cmds=(
  'frequency-info:show current frequency info'
  'frequency-set:set frequency parameters'
  'idle-info:show current idle state info'
  'idle-set:set idle state parameters'
  'info:show global power parameters'
  'set:set global power parameters'
  'monitor:report frequency and idle statistics'
  'help:print usage information'
)
case $state in
  cmds)
    _describe command cmds && ret=0
  ;;
  args)
    curcontext="${curcontext%:*}-$words[1]"
    case ${words[1]} in
      help)
        _describe command cmds
        return
      ;;
      frequency-info)
        args=(
          '(-m --human)'{-m,--human}'[use human readable output]'
          '(-n --no-rounding)'{-n,--no-rounding}'[disable rounding of values]'
          - '(info)'
          {-e,--debug}'[print debug info]'
          {-f,--freq}'[show current frequency]'
          {-w,--hwfreq}'[show current hardware frequency]'
          {-l,--hwlimits}'[show min/max frequency allowed]'
          {-d,--driver}'[show the kernel driver in use]'
          {-p,--policy}'[show the current cpufreq policy]'
          {-g,--governors}'[show available governors]'
          {-r,--related-cpus}'[show cpus that run at the same frequency]'
          {-a,--affected-cpus}'[show software controlled cpus]'
          {-s,--stats}'[show cpufreq statistics]'
          {-y,--latency}'[show frequency change latency]'
        )
        [[ -n $opt_args[(i)-(c|-cpu)] ]] || args+=(
          {-o,--proc}'[print old style proc info]'
        )
      ;;
      frequency-set)
        args=(
          '(-d --min)'{-d+,--min}'[new minimum frequency]:frequency:->frequencies'
          '(-u --max)'{-u+,--max}'[new maximum frequency]:frequency:->frequencies'
          '(-g --governor)'{-g+,--governor}'[new cpufreq governor]:governor:->governors'
          '(-)'{-f+,--freq}'[new frequency for userspace governor]:frequency:->frequencies'
          '(-r --related)'{-r,--related}'[modify all hardware related cpus]'
        )
      ;;
      idle-info)
        args=(
          '(-f --silent)'{-f,--silent}'[print summary only]'
          '(-e --proc)'{-e,--proc}'[print old style proc info (deprecated)]'
        )
      ;;
      idle-set)
        args=(
          '(-d --disable)'{-d+,--disable}'[disable specific sleep state]:state no'
          '(-e --enable)'{-e+,--enable}'[enable specific sleep state]:state no'
          '(-D --disable-by-latency)'{-D+,--disable-by-latency}'[disable state based on latency]:latency'
          '(-E --enable-all)'{-E,--enable-all}'[enable all idle states]'
        )
      ;;
      info)
        args=(
          '(-b --perf-bias)'{-b,--perf-bias}'[show intel performance bias value]'
        )
      ;;
      set)
        args=(
          '(-b --perf-bias)'{-b+,--perf-bias}'[set intel performance bias value]:performance bias'
        )
      ;;
      monitor)
        args=(
          '(-)-l[list available monitors]'
          '-m+[display specified monitors]:monitor:->monitors'
          '-i+[measurement interval]:interval (seconds)'
          '-c[schedule on every core]'
          '-v[increase verbosity]'
          '*:::command: _normal'
        )
      ;;
    esac
    _arguments -C -s "$args[@]" && ret=0
    case $state in
      frequencies)
        _wanted -x frequencies expl frequency compadd $(cpupower frequency-info |
               sed -n 's/ //g; s/,/ /g; s/availablefrequencysteps://p') && ret=0
      ;;
      governors)
        _wanted governors expl 'scaling governor' compadd \
            ${=${"$(_call_program governors cpupower frequency-info -g)"}##*:} && ret=0
      ;;
      monitors)
        _sequence _wanted monitors expl 'monitor' compadd - ${${${(M)${(f)"$(_call_program monitors \
            cpupower monitor -l)"}:#Monitor *}#*\"}%%\"*} && ret=0
      ;;
    esac
  ;;
esac

return ret

${this.title}

Code Editor : _cpupower