Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
zfanon	1.86 KB	-rw-r--r--
zfautocheck	1.29 KB	-rw-r--r--
zfcd	1.89 KB	-rw-r--r--
zfcd_match	1.37 KB	-rw-r--r--
zfcget	2.01 KB	-rw-r--r--
zfclose	90 B	-rw-r--r--
zfcput	2.4 KB	-rw-r--r--
zfdir	3.25 KB	-rw-r--r--
zffcache	662 B	-rw-r--r--
zfgcp	1.91 KB	-rw-r--r--
zfget	1.73 KB	-rw-r--r--
zfget_match	1.5 KB	-rw-r--r--
zfgoto	2.2 KB	-rw-r--r--
zfhere	181 B	-rw-r--r--
zfinit	2.49 KB	-rw-r--r--
zfls	208 B	-rw-r--r--
zfmark	1.41 KB	-rw-r--r--
zfopen	1.16 KB	-rw-r--r--
zfparams	687 B	-rw-r--r--
zfpcp	1.27 KB	-rw-r--r--
zfput	1.41 KB	-rw-r--r--
zfrglob	2.09 KB	-rw-r--r--
zfrtime	1.33 KB	-rw-r--r--
zfsession	1.61 KB	-rw-r--r--
zfstat	1.98 KB	-rw-r--r--
zftp_chpwd	1.35 KB	-rw-r--r--
zftp_progress	2.03 KB	-rw-r--r--
zftransfer	1.53 KB	-rw-r--r--
zftype	553 B	-rw-r--r--
zfuget	3.81 KB	-rw-r--r--
zfuput	2.59 KB	-rw-r--r--

Code Editor : zfsession

# function zfsession {
# Change or list the sessions for the current zftp connection.

emulate -L zsh

[[ $curcontext = :zf* ]] || local curcontext=:zfsession
local opt opt_l opt_v opt_o opt_d hadopts

while getopts ":lovd" opt; do
  [[ $opt = "?" ]] && print "zfsession: bad option: -$OPTARG" >&2 && return 1
  eval "opt_$opt=1"
  hadopts=1
done
(( OPTIND > 1 )) && shift $(( OPTIND - 1 ))

if [[ $# -gt 1 || (( -n $hadopts && -z $opt_d ) && $# -gt 0 ) ]]
then
  print "Usage: zfsession ( [ -lvod ] | session )" 1>&2
  return 1
fi

if [[ -n $opt_v ]]; then
  local sess
  for sess in $(zftp session); do
    print -n "${(r.15.. ..:.)sess}\t${zfconfig[lastloc_$sess]:-not connected}"
    if [[ $sess = $ZFTP_SESSION ]]; then
      print " *"
    else
      print
    fi
  done
elif [[ -n $opt_l ]]; then
  zftp session
fi

if [[ -n $opt_o ]]; then
  if [[ $zfconfig[lastsession] != $ZFTP_SESSION ]]; then
    local cursession=$ZFTP_SESSION
    zftp session $zfconfig[lastsession]
    zfconfig[lastsession]=$cursession
    print $ZFTP_SESSION
  else
    print "zfsession: no previous session." >&2
    return 1
  fi
fi

if [[ -n $opt_d ]]; then
  local del=${1:-$ZFTP_SESSION} key
  key=${zfconfig[fcache_$del]}
  [[ -n $key ]] && unset $key
  for key in fcache lastloc lastdir curdir otherdir otherargs lastuser; do
    unset "zfconfig[${key}_${del}]"
  done
  zftp rmsession $del
  return
fi

[[ -n $hadopts ]] && return $stat

if [[ $# = 0 ]]; then
  print $ZFTP_SESSION
  return
fi

local oldsession=${ZFTP_SESSION:-default}
zftp session $1
if [[ $ZFTP_SESSION != $oldsession ]]; then
  zfconfig[lastsession]=$oldsession
  zftp_chpwd
fi
# }

${this.title}

Code Editor : zfsession