Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
VCS_INFO_detect_bzr	326 B	-rw-r--r--
VCS_INFO_detect_cdv	335 B	-rw-r--r--
VCS_INFO_detect_cvs	325 B	-rw-r--r--
VCS_INFO_detect_darcs	333 B	-rw-r--r--
VCS_INFO_detect_fossil	341 B	-rw-r--r--
VCS_INFO_detect_git	579 B	-rw-r--r--
VCS_INFO_detect_hg	692 B	-rw-r--r--
VCS_INFO_detect_mtn	336 B	-rw-r--r--
VCS_INFO_detect_p4	2.35 KB	-rw-r--r--
VCS_INFO_detect_svk	1.43 KB	-rw-r--r--
VCS_INFO_detect_svn	354 B	-rw-r--r--
VCS_INFO_detect_tla	345 B	-rw-r--r--
VCS_INFO_get_data_bzr	3.54 KB	-rw-r--r--
VCS_INFO_get_data_cdv	305 B	-rw-r--r--
VCS_INFO_get_data_cvs	676 B	-rw-r--r--
VCS_INFO_get_data_darcs	311 B	-rw-r--r--
VCS_INFO_get_data_fossil	654 B	-rw-r--r--
VCS_INFO_get_data_git	12.02 KB	-rw-r--r--
VCS_INFO_get_data_hg	7.91 KB	-rw-r--r--
VCS_INFO_get_data_mtn	410 B	-rw-r--r--
VCS_INFO_get_data_p4	1.08 KB	-rw-r--r--
VCS_INFO_get_data_svk	728 B	-rw-r--r--
VCS_INFO_get_data_svn	2.4 KB	-rw-r--r--
VCS_INFO_get_data_tla	458 B	-rw-r--r--

Code Editor : VCS_INFO_get_data_svn

## vim:ft=zsh
## subversion support by:
##  + Frank Terbeck <ft@bewatermyfriend.org>
##  + Phil Pennock
## Distributed under the same BSD-ish license as zsh itself.

setopt localoptions noksharrays extendedglob NO_shwordsplit
local svnbase svnbranch a b rrn
local -i rc
local -A svninfo parentinfo cwdinfo
local -A hook_com
integer -r SVN_ERR_WC_UPGRADE_REQUIRED=155036 # from /usr/local/include/subversion-1/svn_error_codes.h

svnbase=".";
svninfo=()
# Unfortunately, `$pipestatus' is broken currently. Until that problem is
# resolved, here is a workaround that will get things done, without using it.
# Clumsily, but that's life.
local -a dat
dat=( ${(f)"$(${vcs_comm[cmd]} info --non-interactive 2>&1)"} )
rc=$?
if (( rc != 0 )) ; then
  if (( rc == 1 )) && [[ -n ${(M)dat:#"svn: E${SVN_ERR_WC_UPGRADE_REQUIRED}: "*} ]]; then
    hook_com=()
    VCS_INFO_formats '' '?' '?' '' '' '?' 'upgrade required'
    return $?
  else
    return 1
  fi
fi
# The following line is the real code, the following is the workaround.
#${vcs_comm[cmd]} info --non-interactive \
print -l "${dat[@]}" \
|& while IFS=: read a b; do
    svninfo[${a// /_}]="${b## #}"
done
#rc=${pipestatus[1]}
#(( rc != 0 )) && return 1

cwdinfo=(${(kv)svninfo})

# Set svnbase to the wcroot path and svninfo to its `svn info`.
if (( ${+svninfo[Working_Copy_Root_Path]} )); then
  # svn 1.7+
  svnbase=${svninfo[Working_Copy_Root_Path]}
  ${vcs_comm[cmd]} info --non-interactive -- "${svnbase}" | while IFS=: read a b; do svninfo[${a// /_}]="${b## #}"; done
else
  # svn 1.0-1.6
  svnbase=${svnbase:P}
  while [[ -d "${svnbase:h}/.svn" ]]; do
      parentinfo=()
      ${vcs_comm[cmd]} info --non-interactive -- "${svnbase:h}" | while IFS=: read a b; do parentinfo[${a// /_}]="${b## #}"; done
      [[ ${parentinfo[Repository_UUID]} != ${svninfo[Repository_UUID]} ]] && break
      svninfo=(${(kv)parentinfo})
      svnbase=${svnbase:h}
      if [[ $svnbase == '/' ]]; then
	  break
      fi
  done
fi

rrn=${svnbase:t}
zstyle -s ":vcs_info:${vcs}:${usercontext}:${rrn}" branchformat svnbranch || svnbranch="%b:%r"
hook_com=( branch "${svninfo[URL]##*/}" revision "${cwdinfo[Revision]}" )
if VCS_INFO_hook 'set-branch-format' "${svnbranch}"; then
    zformat -f svnbranch "${svnbranch}" "b:${hook_com[branch]}" "r:${hook_com[revision]}"
else
    svnbranch=${hook_com[branch-replace]}
fi
hook_com=()
VCS_INFO_formats '' "${svnbranch}" "${svnbase}" '' '' "${cwdinfo[Revision]}" ''
return 0

${this.title}

Code Editor : VCS_INFO_get_data_svn