Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
add-zle-hook-widget	5.25 KB	-rw-r--r--
add-zsh-hook	1.9 KB	-rw-r--r--
allopt	783 B	-rw-r--r--
checkmail	817 B	-rwxr-xr-x
colors	3.34 KB	-rw-r--r--
getjobs	827 B	-rw-r--r--
harden	96 B	-rwxr-xr-x
is-at-least	2.23 KB	-rw-r--r--
mere	2.02 KB	-rw-r--r--
nslookup	1.11 KB	-rw-r--r--
promptnl	3.23 KB	-rw-r--r--
regexp-replace	1.01 KB	-rw-r--r--
relative	888 B	-rw-r--r--
run-help	3 KB	-rwxr-xr-x
run-help-git	144 B	-rw-r--r--
run-help-ip	862 B	-rwxr-xr-x
run-help-openssl	59 B	-rw-r--r--
run-help-p4	78 B	-rw-r--r--
run-help-sudo	56 B	-rw-r--r--
run-help-svk	52 B	-rw-r--r--
run-help-svn	52 B	-rw-r--r--
sticky-note	4.59 KB	-rwxr-xr-x
tetris	5.31 KB	-rw-r--r--
tetriscurses	10.76 KB	-rw-r--r--
xtermctl	4.09 KB	-rw-r--r--
zargs	8.73 KB	-rw-r--r--
zcalc	11.92 KB	-rwxr-xr-x
zed	4 KB	-rwxr-xr-x
zkbd	7.12 KB	-rwxr-xr-x
zmathfuncdef	2.23 KB	-rw-r--r--
zmv	11.14 KB	-rw-r--r--
zrecompile	6.04 KB	-rw-r--r--
zstyle+	1.24 KB	-rw-r--r--
ztodo	1.37 KB	-rw-r--r--

Code Editor : zmathfuncdef

# Define a mathematical function with its definition and smart(ish)
# guessing of the number of arguments.  Doesn't overload for different
# numbers of arguments, but that could be done.  Type overloading would be
# more fraught.

emulate -L zsh
setopt extendedglob
local -a match mbegin mend line
local func

if (( $# > 2 )); then
  print "Usage: $0 [name [body]]" >&2
  return 1
fi

zmodload -i zsh/parameter || return 1

if (( $# == 0 )); then
  functions -M | while read -A line; do
    func=${functions[$line[6]]}
    if [[ $func = (#b)[[:space:]]#$\([[:space:]]#(*[^[:space:]])[[:space:]]#$\) ]]; then
      print "zmathfuncdef $line[3] ${(qq)match[1]}"
    fi
  done
  return 0
fi

local mname=$1
local fname="zsh_math_func_$1"

if (( $# == 1 )); then
  functions +M $mname && unfunction $fname
  return 0
elif [[ -n $functions[$fname] ]]; then
  functions +M $mname
fi

integer iarg=0 ioptarg
local body=$2

# count compulsory arguments
while [[ $body = *'$'(\{|)$((iarg+1))(|[^:[:digit:]]*) ]]; do
  (( iarg++ ))
done

# count optional arguments
(( ioptarg = iarg ))
while [[ $body = *'${'$((ioptarg+1))':-'* ]]; do
  (( ioptarg++ ))
done

functions -M $mname $iarg $ioptarg $fname || return 1

# See if we need to autoload a math function from the standard
# library.
if ! zmodload -e zsh/mathfunc; then
  local -a mathfuncs match mbegin mend loads
  local mathfuncpat bodysearch

# generate pattern to match all known math functions
  mathfuncs=(abs acos acosh asin asinh atan atanh cbrt ceil cos cosh erf erfc
    exp expm1 fabs float floor gamma int j0 j1 lgamma log log10 log1p logb
    sin sinh sqrt tan tanh y0 y1 signgam copysign fmod hypot nextafter jn yn
    ldexp scalb rand48)
  mathfuncpat="(${(j.|.)mathfuncs})"
  bodysearch=$body
  while [[ $bodysearch = (#b)(*[^[:alnum]]|)([[:alnum:]]##)\((*) ]]; do
    # save worrying about search order...
    bodysearch=$match[1]$match[3]
    if [[ $match[2] = ${~mathfuncpat} ]]; then
      # Uses function from math library.
      loads+=($match[2])
    fi
  done
  if (( ${#loads} )); then
    zmodload -af zsh/mathfunc $loads
  fi
fi

{
  eval "$fname() { (( $body )) }"
} always {
  # Remove math function if shell function definition failed.
  if (( TRY_BLOCK_ERROR )); then
    functions +M $mname
  fi
}

${this.title}

Code Editor : zmathfuncdef