Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
_add-zle-hook-widget	942 B	-rw-r--r--
_add-zsh-hook	648 B	-rw-r--r--
_alias	711 B	-rw-r--r--
_aliases	708 B	-rw-r--r--
_arrays	84 B	-rw-r--r--
_assign	64 B	-rw-r--r--
_autocd	85 B	-rw-r--r--
_bindkey	1.95 KB	-rw-r--r--
_brace_parameter	5.73 KB	-rw-r--r--
_builtin	190 B	-rw-r--r--
_cd	3.99 KB	-rw-r--r--
_command	257 B	-rw-r--r--
_command_names	1.42 KB	-rw-r--r--
_compadd	2.37 KB	-rw-r--r--
_compdef	1.99 KB	-rw-r--r--
_completers	400 B	-rw-r--r--
_condition	1.74 KB	-rw-r--r--
_default	682 B	-rw-r--r--
_delimiters	330 B	-rw-r--r--
_directory_stack	1.39 KB	-rw-r--r--
_dirs	262 B	-rw-r--r--
_disable	683 B	-rw-r--r--
_dynamic_directory_name	378 B	-rw-r--r--
_echotc	93 B	-rw-r--r--
_echoti	94 B	-rw-r--r--
_emulate	274 B	-rw-r--r--
_enable	692 B	-rw-r--r--
_equal	33 B	-rw-r--r--
_exec	218 B	-rw-r--r--
_fc	3 KB	-rw-r--r--
_file_descriptors	1.44 KB	-rw-r--r--
_first	1.59 KB	-rw-r--r--
_functions	233 B	-rw-r--r--
_globflags	1.08 KB	-rw-r--r--
_globqual_delims	466 B	-rw-r--r--
_globquals	6.55 KB	-rw-r--r--
_hash	1.1 KB	-rw-r--r--
_history_modifiers	1.99 KB	-rw-r--r--
_in_vared	813 B	-rw-r--r--
_jobs	1.94 KB	-rw-r--r--
_jobs_bg	27 B	-rw-r--r--
_jobs_builtin	360 B	-rw-r--r--
_jobs_fg	31 B	-rw-r--r--
_kill	678 B	-rw-r--r--
_limit	166 B	-rw-r--r--
_limits	105 B	-rw-r--r--
_math	483 B	-rw-r--r--
_math_params	60 B	-rw-r--r--
_mere	57 B	-rw-r--r--
_module_math_func	306 B	-rw-r--r--
_options	182 B	-rw-r--r--
_options_set	299 B	-rw-r--r--
_options_unset	309 B	-rw-r--r--
_parameter	37 B	-rw-r--r--
_parameters	975 B	-rw-r--r--
_precommand	133 B	-rw-r--r--
_print	4.05 KB	-rw-r--r--
_prompt	296 B	-rw-r--r--
_ps1234	5.66 KB	-rw-r--r--
_read	919 B	-rw-r--r--
_redirect	421 B	-rw-r--r--
_run-help	203 B	-rw-r--r--
_sched	467 B	-rw-r--r--
_set	1.44 KB	-rw-r--r--
_setopt	571 B	-rw-r--r--
_source	226 B	-rw-r--r--
_strftime	304 B	-rw-r--r--
_subscript	4.22 KB	-rw-r--r--
_suffix_alias_files	525 B	-rw-r--r--
_tcpsys	925 B	-rw-r--r--
_tilde	732 B	-rw-r--r--
_trap	101 B	-rw-r--r--
_ttyctl	113 B	-rw-r--r--
_typeset	5.69 KB	-rw-r--r--
_ulimit	1020 B	-rw-r--r--
_unhash	400 B	-rw-r--r--
_user_math_func	188 B	-rw-r--r--
_value	1.6 KB	-rw-r--r--
_vared	432 B	-rw-r--r--
_vars	504 B	-rw-r--r--
_wait	66 B	-rw-r--r--
_which	1.26 KB	-rw-r--r--
_widgets	193 B	-rw-r--r--
_zargs	2.01 KB	-rw-r--r--
_zattr	597 B	-rw-r--r--
_zcalc	217 B	-rw-r--r--
_zcalc_line	1.7 KB	-rw-r--r--
_zcompile	927 B	-rw-r--r--
_zed	283 B	-rw-r--r--
_zftp	2.52 KB	-rw-r--r--
_zle	2.71 KB	-rw-r--r--
_zmodload	2.77 KB	-rw-r--r--
_zmv	805 B	-rw-r--r--
_zparseopts	1.32 KB	-rw-r--r--
_zpty	2.04 KB	-rw-r--r--
_zsh-mime-handler	719 B	-rw-r--r--
_zsocket	384 B	-rw-r--r--
_zstyle	19.05 KB	-rw-r--r--
_ztodo	586 B	-rw-r--r--

Code Editor : _typeset

#compdef autoload declare export functions integer float local readonly typeset

local expl state line func i use curcontext="$curcontext"
local fopts="-f -k -z +k +z"
local popts="-A -E -F -L -R -T -Z -a -g -h -H -i -l -r -x"
local -A allargs opt_args
local -a args

allargs=(
  A "($fopts -E -F -L -R -T -U -Z -a -i -m)-A[specify that arguments refer to associative arrays]"
  E "($fopts -A -F -L -R -T -U -Z -a -i -m)-E[floating point, use engineering notation on output]"
  F "($fopts -A -E -L -R -T -U -Z -a -i -m)-F[floating point, use fixed point decimal on output]"
  L "($fopts -A -E -F -i)-L+[left justify and remove leading blanks from value]:width"
  R "($fopts -A -E -F -i)-R+[right justify and fill with leading blanks]:width"
  T "($fopts -A -E -F -a -g -h -i -l -m -t)-T[tie scalar to array or trace function]"
  Tf "($popts -t)-T[trace execution of this function only]"
  Tp "($fopts -A -E -F -a -g -h -i -l -m -t)-T[tie scalar to array]"
  U '(-A -E -F -i)-U[keep array values unique and suppress alias expansion for functions]'
  Uf '-U[suppress alias expansion for functions]'
  Up '(-E -F -i)-+U[keep array values unique]'
  X '+X[immediately autoload function]'
  Z "($fopts -A -E -F -i)-Z+[right justify and fill with leading zeros]:width"
  a "($fopts -A -E -F -T -i)-a[specify that arguments refer to arrays]"
  df "-d[default absolute path autoload to fpath]"
  f "($popts)-f[specify that arguments refer to functions]"
  g "($fopts -T)-+g[do not restrict parameter to local scope]"
  h "($fopts -T)-+h[hide specialness of parameter]"
  H "($fopts -T)-+H[hide value of parameter in listings]"
  i "($fopts -A -E -F -T)-+i[represent internally as an integer]"
  k "($popts -w -z)-+k[mark function for ksh-style autoloading]"
  l "($popts -T)-l[convert the value to lowercase]"
  m '(-A -E -F -T -i)-m[treat arguments as patterns]'
  p '-p+[output parameters in form of calls to typeset]::option:((1\:multi-line\ output\ of\ arrays))'
  r '(-f)-+r[mark parameters as readonly]'
  rf '-r[remember autoload path]'
  Rf '-R[remember autoload path, error if not found]'
  t '(-T)-+t[tag parameters and turn on execution tracing for functions]'
  tf '(-T)-+t[turn on execution tracing for functions]'
  tp '(-T)-+t[tag parameters]'
  u '-u[convert the value to uppercase or mark function for autoloading]'
  uf '-u[mark function for autoloadling]'
  up '-u[convert the value to uppercase]'
  w '(-k -z)-w[specify that arguments refer to files compiled with zcompile]'
  W '-+W[turn on WARN_NESTED_VAR for function]'
  x "($fopts)-+x[export parameter]"
  z "($popts -k -w)-+z[mark function for zsh-style autoloading]"
)

use="AEFHLRTUZafghiklmprtuxz"

case ${service} in
  autoload)
    use="URTXdkrtwz"
    func=f
  ;;
  float) use="EFHghlprtux";;
  functions)
    use="UkmTtuzW"
    func=f
    args=(
      '(-k -t -T -u -U -W -x -z -M +M +k +t +W +z)-+M[define mathematical function]'
      '(-k -m -t -T -u -U -W -x -z +M +k +t +W +z)-s[define mathematical function that takes a string argument]'
      '(-M)-x+[specify spaces to use for indentation]:spaces'
      '(-* +*)-c[copy shell function to another name]:old name:_functions:new name:_functions'
    )
  ;;
  integer)
    use="Hghilprtux"
    allargs[i]='-i+[specify arithmetic base for output]:: :_guard "[0-9]#" base' \
  ;;
  readonly) use="${use/r/}" ;;
  local) use="${use/[fkz]/}" ;&
  export) use="${${use//[gkz]/}/x/}" ;;
esac

[[ -z "${words[(r)-*[aA]*]}" ]] || func=p
[[ -z "${words[(r)-*f*]}" ]] || func=f

# This function uses whacky features of _arguments which means we
# need to look for options to the command beforehand.
local onopts offopts
onopts=${(j..)${${words[1,CURRENT-1]:#^-*}##-}}
offopts=${(j..)${${words[1,CURRENT-1]:#^+*}##+}}

for ((i=1;i<=$#use;++i)); do
  args+=( ${allargs[${use[$i]}${${(s::)use[$i]}[(r)[dUurRtT]]:+$func}]} )
done

_arguments -C -s -A "-*" -S "${args[@]}" '*::vars:= ->vars_eq'

if [[ "$state" = vars_eq ]]; then
  if [[ $func = f ]]; then
    if (( $+opt_args[+M] || ( $+opt_args[-M] && $+opt_args[-m] ) )); then
      _wanted functions expl 'math function' compadd -F line - \
          ${${${(f)"$(functions -M)"}##*-M }%% *}
    elif (( $+opt_args[-M] )); then
      _arguments ':new math function:_functions' \
	":minimum arguments${(k)opt_args[-s]:+:(1)}" \
	":maximum arguments${(k)opt_args[-s]:+:(1)}" \
	':shell function:_functions'
    elif (( $+opt_args[-w] )); then
      _wanted files expl 'zwc file' _files -g '*.zwc(-.)'
    elif [[ $service = autoload || -n $opt_args[(i)-[uU]] ]]; then
      if [[ $PREFIX[1] = [/~] ]]; then
	# Autoload by absolute path
	_files
      else
	  args=(${^fpath}/*(-.:t))
	  # Filter out functions already loaded or marked for autoload.
	  local -a funckeys
	  funckeys=(${(k)functions})
	  args=(${args:|funckeys})
	  _wanted functions expl 'shell function' compadd -a args
      fi
    elif [[ -n $onopts$offopts ]]; then
      if [[ -n $offopts ]]; then
	args=(${(f)"$(functions +${offopts//[^UXkmtTuz]/})"})
      else
	args=(${(k)functions})
      fi
      if [[ -n $onopts ]]; then
	local -a funckeys
	funckeys=(${(f)"$(functions +${onopts//[^UXkmtTuz]/})"})
	args=(${args:|funckeys})
      fi
      if zstyle -t ":completion:${curcontext}:functions" prefix-needed &&
	[[ $PREFIX != [_.]* ]]; then
	args=(${args:#_*})
      fi
      _wanted functions expl 'shell functions' compadd -a args
    else
      _functions
    fi
  elif [[ "$PREFIX" = *\=* ]]; then
    compstate[parameter]="${PREFIX%%\=*}"
    compset -P 1 '*='
    _value
  elif (( $+opt_args[-a] || $+opt_args[-A] )); then
    _parameters -q
  elif (( $+opt_args[-T] )); then
    _arguments \
      ':scalar parameter:_parameters -g "*scalar*" -q -S "="' \
      ':array parameter:_parameters -g "*array*"' \
      ':separator character'
  else
    _parameters -q -S '='
  fi
fi

${this.title}

Code Editor : _typeset