Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
_acroread	3.42 KB	-rw-r--r--
_code	2.54 KB	-rw-r--r--
_dcop	2.88 KB	-rw-r--r--
_eog	1.26 KB	-rw-r--r--
_evince	1.61 KB	-rw-r--r--
_geany	1.97 KB	-rw-r--r--
_gnome-gv	139 B	-rw-r--r--
_gqview	619 B	-rw-r--r--
_gv	1.28 KB	-rw-r--r--
_kdeconnect	1.87 KB	-rw-r--r--
_kfmclient	3.19 KB	-rw-r--r--
_matlab	1.4 KB	-rw-r--r--
_mozilla	4.67 KB	-rw-r--r--
_mplayer	8.15 KB	-rw-r--r--
_mupdf	733 B	-rw-r--r--
_nautilus	538 B	-rw-r--r--
_nedit	2.8 KB	-rw-r--r--
_netscape	2.87 KB	-rw-r--r--
_okular	332 B	-rw-r--r--
_pdftk	1.34 KB	-rw-r--r--
_qiv	3.9 KB	-rw-r--r--
_rdesktop	3.71 KB	-rw-r--r--
_setxkbmap	2.54 KB	-rw-r--r--
_sublimetext	605 B	-rw-r--r--
_urxvt	2.76 KB	-rw-r--r--
_vnc	4.06 KB	-rw-r--r--
_x_arguments	600 B	-rw-r--r--
_x_borderwidth	125 B	-rw-r--r--
_x_color	1007 B	-rw-r--r--
_x_colormapid	396 B	-rw-r--r--
_x_cursor	409 B	-rw-r--r--
_x_display	75 B	-rw-r--r--
_x_extension	484 B	-rw-r--r--
_x_font	286 B	-rw-r--r--
_x_geometry	125 B	-rw-r--r--
_x_keysym	615 B	-rw-r--r--
_x_locale	120 B	-rw-r--r--
_x_modifier	153 B	-rw-r--r--
_x_name	116 B	-rw-r--r--
_x_resource	124 B	-rw-r--r--
_x_selection_timeout	130 B	-rw-r--r--
_x_title	118 B	-rw-r--r--
_x_utils	6.33 KB	-rw-r--r--
_x_visual	272 B	-rw-r--r--
_x_window	402 B	-rw-r--r--
_xauth	2.52 KB	-rw-r--r--
_xautolock	631 B	-rw-r--r--
_xclip	1.03 KB	-rw-r--r--
_xdvi	1.66 KB	-rw-r--r--
_xfig	1.93 KB	-rw-r--r--
_xft_fonts	1.32 KB	-rw-r--r--
_xloadimage	3.81 KB	-rw-r--r--
_xmodmap	2.22 KB	-rw-r--r--
_xournal	126 B	-rw-r--r--
_xpdf	1.72 KB	-rw-r--r--
_xrandr	2.61 KB	-rw-r--r--
_xscreensaver	823 B	-rw-r--r--
_xset	5.08 KB	-rw-r--r--
_xt_arguments	1.7 KB	-rw-r--r--
_xt_session_id	40 B	-rw-r--r--
_xterm	1.19 KB	-rw-r--r--
_xv	2.43 KB	-rw-r--r--
_xwit	4.63 KB	-rw-r--r--
_zeal	1.33 KB	-rw-r--r--

Code Editor : _rdesktop

#compdef rdesktop xfreerdp

local curcontext="$curcontext" state line expl args redir ret=1
typeset -A opt_args

case $service in
  rdesktop)
    args=(
      '(-5)-4[use RDP version 4]'
      '(-4)-5[use RDP version 5]'
      '-b[force server to use bitmaps for screen updates]'
      '-B[use X server backing store]'
      '-E[disable encryption]'
      "-m[don't send mouse motion events]"
      '-C[use private colormap]'
      '-S[single application mode]'
      '-N[enable numlock synchronisation]'
      '-P[enable bitmap caching]'
      '*-r[device redirection]: :->redirection'
    )
  ;;
  xfreerdp)
    args=(
      '(-)'{-h,--help}'[display help information]'
      "-o[don't redirect audio to client]"
      '-s[set startup-shell]:shell'
      '-t[connect to specified port]:port:_ports'
      '--app[RemoteApp connection]'
      '--ext[load an extension]:extension'
      '--no-auth[disable authentication]'
      '--authonly[authentication only, no UI]'
      '--from-stdin[prompt for username, password, domain and hostname]'
      '--no-fastpath[disable fast-path]'
      '--gdi[graphics rendering]:backend:(hw sw)'
      "--no-motion[don't send mouse motion events]"
      '--no-osb[disable offscreen bitmaps]'
      '--no-bmp-cache[disable bitmap cache]'
      '--plugin[load a virtual channel plugin]:(cliprdr drdynvc rdpsnd rail rdpdbg rdpdr)'
      '--rfx[enable RemoteFX]'
      '--rfx-mode[RemoteFX operational flags]:mode:((v\:video i\:image))'
      '--nsc[enable NSCodec]'
      '--disable-wallpaper'
      '--composition[enable desktop composition]'
      '--disable-full-window-drag'
      '--disable-menu-animations'
      '--disable-theming'
      '--kbd-list[list all keyboard layout ids used by -k]'
      '--no-rdp[disable Standard RDP encryption]'
      '--no-tls[disable TLS encryption]'
      '--no-nla[disable network level authentication]'
      '--ntlm[force NTLM authentication protocol version]:version:(1 2)'
      '--certificate-name[specify logon certificate]:certificate'
      '--ignore-certificate[ignore verification of logon certificate]'
      '--sec[force protocol security]:security:(rdp tls nla)'
      '--secure-checksum[use salted checksums with Standard RDP encryption]'
      '--version[print version information]'
    )
  ;;
esac

_arguments -C -s $args \
  '-u[username]:username:_users' \
  '-d[domain]:domain' \
  '-s[shell]:startup shell' \
  '-c[working directory]:directory:_directories' \
  '-p[password]:password' \
  '-n[set reported client hostname]:client hostname:_hosts' \
  '-k[keyboard map]:keyboard map' \
  '(-f)-g[geometry]:geometry (WxH)' \
  '(-g)-f[fullscreen mode]' \
  '-D[hide window decorations]' \
  '-K[do not override window manager key bindings]' \
  '-T[set window title]:title' \
  '-X[embed in another window]:window:_x_window' \
  '-a[colour depth]:depth:(8 15 16 24 32)' \
  '-z[enable compression]' \
  '-x[bandwidth performance behaviour]:experience:((b\:broadband l\:lan m\:modem))' \
  '-0[attach to server console]' \
  ':server:->hostsport' && ret=0

case $state in
  hostsport)
    if compset -P '*:'; then
      _ports && ret=0
    else
      compset -S ':*'
      _hosts && ret=0
    fi
  ;;
  redirection)
    redir="${PREFIX%%:*}"
    if compset -P 1 '*='; then
      curcontext="${curcontext%:*}:$redir"
      case $redir in
	comport|lptport) _wanted devices expl device _files -g '*(-%)' && ret=0 ;;
	disk) _directories && ret=0 ;;
	printer) _printers && ret=0 ;;
	scard) _message -e aliases 'alias name' ;;
      esac
    else
      compset -S '=*'
      _values -S : 'redirection' \
	'comport:port' \
	'disk:sharename' \
	'lptport:lptport' \
	'printer:printername:_printers -S=' \
	'sound:sound:(local off remote)' \
	'lspci' \
	'scard:sound card name' && ret=0
    fi
  ;;
esac
 
return ret

${this.title}

Code Editor : _rdesktop