Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
_be_name	341 B	-rw-r--r--
_beadm	2 KB	-rw-r--r--
_coreadm	1.45 KB	-rw-r--r--
_dhcpinfo	1.17 KB	-rw-r--r--
_dladm	27.48 KB	-rw-r--r--
_dtrace	2.07 KB	-rw-r--r--
_dumpadm	866 B	-rw-r--r--
_flowadm	2.69 KB	-rw-r--r--
_fmadm	2.8 KB	-rw-r--r--
_inetadm	406 B	-rw-r--r--
_ipadm	12.31 KB	-rw-r--r--
_pfexec	751 B	-rw-r--r--
_pkg5	12.15 KB	-rw-r--r--
_prstat	1.79 KB	-rw-r--r--
_ptree	209 B	-rw-r--r--
_savecore	228 B	-rw-r--r--
_snoop	1.45 KB	-rw-r--r--
_svcadm	1.79 KB	-rw-r--r--
_svccfg	3.87 KB	-rw-r--r--
_svcprop	793 B	-rw-r--r--
_svcs	1.12 KB	-rw-r--r--
_svcs_fmri	2.83 KB	-rw-r--r--
_zlogin	472 B	-rw-r--r--
_zoneadm	3.97 KB	-rw-r--r--
_zones	256 B	-rw-r--r--

Code Editor : _svccfg

#compdef svccfg

local curcontext="$curcontext" ret=1
local -a state line expl subcmds args
local -A opt_args

# Subcommands that don't make sense on the commandline are missing
subcmds=(
  apply export extract import inventory validate
  add delete list
  addpg addpropvalue delcust delpg delprop delpropvalue describe
  editprop listpg listprop listcust setenv setprop unsetenv
  setnotify listnotify delnotify
  listsnap revert selectsnap
  refresh
  help
)

_arguments -s -A "-*" \
  '-v[verbose]' \
  '-s+[specify fmri on which to operate]:fmri:_svcs_fmri -c' \
  '(1 *)-f+[read commands from file]:command file:_files' \
  '1: :->subcmds' \
  '*:: :->args' && ret=0

case $state in
  subcmds)
    _wanted commands expl 'svccfg subcommand' compadd -a subcmds && ret=0
  ;;
  args)
    curcontext="${curcontext%:*}-$words[1]:"

case $words[1] in
      import)
        _arguments \
          '-V[verify property updates]' \
          ':file:_files'
      ;;

apply|inventory) _files ;;

validate)
        _alternative 'files:file:_files' 'fmris:fmri:_svcs_fmri -c'
      ;;

export) _svcs_fmri -c ;;

delete)
        _arguments \
          '-f[force deletion if online or degraded]' \
          '*:fmri:_svcs_fmri -c'
      ;;

describe)
        local fmri=$opt_args[-s]
        _arguments -A "-*" \
          '-v[give all information]' \
          '-t[show only template data]' \
          ':property group or property:->properties'

if [[ -n $state ]]; then
          fmris=( ${(f)"$(_call_program properties svcs -H -o fmri $fmri)"} )
          if (( $#fmris > 1 )); then
            _message "'$fmri' is ambiguous"
            return 1
          fi

# Get all the property names for the FMRI
          props=( ${${${(f)"$(_call_program properties svccfg -s $fmri describe)"}:# *}%% *} )

_multi_parts "$@" - / props && ret=0
        fi
      ;;

listprop)
        _arguments \
          '-l+[print the layer the value came from]:layer:(manifest system-profile enterprise-profile site-profile node-profile sysconfig-profile admin current all)' \
          '(-o)-f[print the file a property came from]' \
          '(-f)-o+[select fields to print]:field:_sequence compadd - propname pgname instname servicename layer proptype value file masked time' \
          '*-G+[specify property group]:property group' \
          '-P+[specify property name]:property name' && ret=0
      ;;

setnotify)
        args=( '2:notification parameter:->parameters' )
      ;&
      listnotify|delnotify|selectsnap)
        _arguments $args \
          '-g[apply to notification parameters in svc:/system/svc/global:default]' \
          '1: :->tsets-classes'

case $state in
          tsets-classes)
            local states=( uninitialized offline online degraded maintenance disabled )
            _alternative \
              'state-transitions:state transition:_sequence compadd - all {to-,from-,}$^states' \
              'event-classes:event class:_sequence compadd - problem-{diagnosed,updated,repaired,resolved}' && ret=0
          ;;
          parameters)
            if compset -P 'mailto:'; then
              _email_addresses -c && ret=0
            elif compset -P 'snmp:'; then
              _wanted values expl value compadd active inactive && ret=9
            else
              _wanted uri-formats expl 'URI format' compadd -S: mailto snmp && ret=0
            fi
          ;;
        esac
      ;;

revert)
        _wanted snapshots expl snapshot compadd initial previous running start && ret=0
      ;;

refresh|listsnap)
        _message 'no more arguments'
      ;;
      *) # fallback to default completion for unknown subcommands
        _default && ret=0
      ;;
    esac
  ;;
esac

return ret

${this.title}

Code Editor : _svccfg