Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
_all_labels	920 B	-rw-r--r--
_all_matches	970 B	-rw-r--r--
_alternative	1.93 KB	-rw-r--r--
_approximate	3.39 KB	-rw-r--r--
_arg_compile	7.39 KB	-rw-r--r--
_arguments	17.09 KB	-rw-r--r--
_bash_completions	1.33 KB	-rw-r--r--
_cache_invalid	707 B	-rw-r--r--
_call_function	737 B	-rw-r--r--
_call_program	853 B	-rw-r--r--
_combination	2.44 KB	-rw-r--r--
_comp_locale	572 B	-rw-r--r--
_complete	3.09 KB	-rw-r--r--
_complete_debug	1 KB	-rw-r--r--
_complete_help	2.59 KB	-rw-r--r--
_complete_help_generic	412 B	-rw-r--r--
_complete_tag	1.98 KB	-rw-r--r--
_correct	518 B	-rw-r--r--
_correct_filename	1.93 KB	-rw-r--r--
_correct_word	388 B	-rw-r--r--
_describe	3.62 KB	-rw-r--r--
_description	3.11 KB	-rw-r--r--
_dispatch	2.01 KB	-rw-r--r--
_expand	7.34 KB	-rw-r--r--
_expand_alias	2.02 KB	-rw-r--r--
_expand_word	307 B	-rw-r--r--
_extensions	1018 B	-rw-r--r--
_external_pwds	1.04 KB	-rw-r--r--
_generic	328 B	-rw-r--r--
_guard	177 B	-rw-r--r--
_history	1.44 KB	-rw-r--r--
_history_complete_word	3.37 KB	-rw-r--r--
_ignored	1.61 KB	-rw-r--r--
_list	822 B	-rw-r--r--
_main_complete	11.02 KB	-rw-r--r--
_match	2.37 KB	-rw-r--r--
_menu	558 B	-rw-r--r--
_message	840 B	-rw-r--r--
_most_recent_file	883 B	-rw-r--r--
_multi_parts	8.59 KB	-rw-r--r--
_next_label	600 B	-rw-r--r--
_next_tags	3.38 KB	-rw-r--r--
_normal	1.1 KB	-rw-r--r--
_nothing	90 B	-rw-r--r--
_oldlist	1.87 KB	-rw-r--r--
_pick_variant	1.15 KB	-rw-r--r--
_prefix	1.58 KB	-rw-r--r--
_read_comp	3.76 KB	-rw-r--r--
_regex_arguments	2.44 KB	-rw-r--r--
_regex_words	936 B	-rw-r--r--
_requested	268 B	-rw-r--r--
_retrieve_cache	732 B	-rw-r--r--
_sep_parts	3.72 KB	-rw-r--r--
_sequence	1.32 KB	-rw-r--r--
_set_command	815 B	-rw-r--r--
_setup	2.19 KB	-rw-r--r--
_store_cache	1.88 KB	-rw-r--r--
_sub_commands	136 B	-rw-r--r--
_tags	1.43 KB	-rw-r--r--
_user_expand	3.68 KB	-rw-r--r--
_values	3.73 KB	-rw-r--r--
_wanted	183 B	-rw-r--r--

Code Editor : _read_comp

#compdef -k complete-word \C-x\C-r

# This allows an on-the-fly choice of completions.  On typing the key
# sequence given above, you will be prompted for a string of arguments.  If
# this string begins with `_', it will be taken as the name of a function to
# evaluate to generate the completions; unambiguous strings in the function
# name are automatically completed.
#
# Else it is taken to be a set of arguments for compadd to generate a list
# of choices.  The possibilities are the same as the flags for generating
# completions given in the zshcompwid manual page.  Note the arguments are
# verbatim:  include minus signs, spaces, quotes, etc.
#
# On subsequent calls, the same completion will be re-performed.  To
# force a new type of completion to be read, supply a numeric argument.
#
# For example,
#  % bindkey | grep rever<C-xC-r>
#  Completion: -b<RET>
#  % bindkey | grep reverse-menu-complete _
#
# Global variables used:
#  _read_comp         Last completion string read from user

# emulate -L zsh
setopt localoptions extendedglob nobadpattern unset # xtrace promptsubst
# local PS4='%N:%i:$((#key))> '

typeset -g _read_comp
if [[ ${+NUMERIC} = 0 && -n $_read_comp ]]; then
  if [[ $_read_comp = _* ]]; then
    eval $_read_comp
  else
    eval "compadd $_read_comp"
  fi
  return
fi

_read_comp=

local key search str str2 newch funcs funcs2 exact msg list
integer pos

msg="Completion: "

zle -R $msg

if ! read -k key; then
  zle -cR ''
  return 1
fi

while [[ '#key' -ne 10 && '#key' -ne 13 ]]; do
  if [[ '#key' -eq 0 && '#key' -eq 3 || '#key' -eq 7 ]]; then
    zle -cR ''
    return 1
  fi
  if [[ ( '#key' -eq 8 || '#key' -eq 127 ) && -n $str ]]; then
    # delete character
    str="$str[1,-2]"
    exact=
    list=()
  elif [[ '#key' -eq 21 ]]; then
    # ^U: delete line
    str=
    exact=
    list=()
  elif [[ '#key' -eq 4 && $str = _[^\ ]# && $str != *' '* ]]; then
    # ^D: list completions
    list=(${$(whence -m "$str*" 2>/dev/null)%: function})
  elif [[ ( -n $exact && $key != ' ' ) || '#key & 127' -lt 32 ]]; then
    # If we've got an exact function, only allow a space after it.
    # Don't try to insert non-printing characters.
    if [[ -n $ZBEEP ]]; then
      print -nb $ZBEEP
    elif [[ -o beep ]]; then
      print -n "\a"
    fi
    list=()
  else
    str="$str$key"
    if [[ $str = _[^\ ]# ]]; then
      # Rudimentary completion for function names.
      # Allow arguments, i.e. don't do this after we've got a space.
      funcs=(${$(whence -m "$str*" 2>/dev/null)%: function})
      if [[ -o autolist && $#str -gt 1 ]]; then
	list=($funcs)
      else
	list=()
      fi
      if (( $#funcs == 1 )); then
	# Exact match; prompt the user for a newline to confirm
	str=$funcs[1]
	exact=" (Confirm)"
      elif (( $#funcs == 0 )); then
	# We can't call zle beep, because this isn't a zle widget.
	if [[ -n $ZBEEP ]]; then
	  print -nb $ZBEEP
	elif [[ -o beep ]]; then
	  print -n "\a"
	fi
	str="$str[1,-2]"
	list=()
      else
	# Add characters to the string until a name doesn't
	# match any more, then backtrack one character to get
	# the longest unambiguous match.
	str2=$str
	pos=$#str2
	while true; do
	  (( pos++ ))
	  newch=${funcs[1][pos]}
	  [[ -z $newch ]] && break
	  str2=$str2$newch
	  funcs2=(${funcs##$str2*})
	  (( $#funcs2 )) && break
	  str=$str2
	done
      fi
    else
      exact=
    fi
  fi
  if (( $#list )); then
    zle -R "$msg$str$exact" $list
  else
    zle -cR "$msg$str$exact"
  fi
  if ! read -k key; then
    zle -cR ''
    return 1
  fi
done

if [[ -z $str ]]; then
  # string must be non-zero
  return 1
elif [[ $str = _* ]] && ! whence ${str%% *} >& /dev/null; then
  # a function must be known to the shell
  return 1
else
  # remember the string for re-use
  _read_comp=$str
fi

zle -cR ''

if [[ $str = _* ]]; then
  eval $str
else
  eval "compadd $str"
fi

${this.title}

Code Editor : _read_comp