Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
_bsd_disks	470 B	-rw-r--r--
_bsd_pkg	8.65 KB	-rw-r--r--
_bsdconfig	2.33 KB	-rw-r--r--
_bsdinstall	1.89 KB	-rw-r--r--
_chflags	574 B	-rw-r--r--
_csup	1.1 KB	-rw-r--r--
_cu	2.51 KB	-rw-r--r--
_cvsup	937 B	-rw-r--r--
_fbsd_architectures	142 B	-rw-r--r--
_fbsd_device_types	934 B	-rw-r--r--
_fetch	3.16 KB	-rw-r--r--
_file_flags	1.5 KB	-rw-r--r--
_freebsd-update	1.12 KB	-rw-r--r--
_fstat	530 B	-rw-r--r--
_fw_update	294 B	-rw-r--r--
_gstat	490 B	-rw-r--r--
_jail	2.41 KB	-rw-r--r--
_jails	747 B	-rw-r--r--
_jexec	544 B	-rw-r--r--
_jls	705 B	-rw-r--r--
_jot	2.47 KB	-rw-r--r--
_kld	1 KB	-rw-r--r--
_ldap	2.19 KB	-rw-r--r--
_mixerctl	577 B	-rw-r--r--
_nbsd_architectures	502 B	-rw-r--r--
_obsd_architectures	178 B	-rw-r--r--
_pfctl	4.78 KB	-rw-r--r--
_pkgin	2.59 KB	-rw-r--r--
_portaudit	563 B	-rw-r--r--
_portlint	748 B	-rw-r--r--
_portmaster	3.89 KB	-rw-r--r--
_portsnap	1.03 KB	-rw-r--r--
_powerd	743 B	-rw-r--r--
_procstat	1.03 KB	-rw-r--r--
_rcctl	1.02 KB	-rw-r--r--
_signify	1.37 KB	-rw-r--r--
_sockstat	1.33 KB	-rw-r--r--
_sysrc	2.9 KB	-rw-r--r--
_systat	2.85 KB	-rw-r--r--
_vmctl	2.87 KB	-rw-r--r--
_watch-snoop	396 B	-rw-r--r--

Code Editor : _jot

#compdef jot

local curcontext="$curcontext" state state_descr line ret=1
local -A opt_args

_arguments -s -C : \
  '(-b)-r[generate random data instead of the default sequential data]' \
  '(-c -p -r -w)-b+[just print the specified word repeatedly]:word:' \
  '(-b -c -p)-w+[specify output format as in printf]:output format:->format' \
  '(-b -p -w)-c[same as -w %c]' \
  '-s+[separate the data by the specified string instead of newline]:string:' \
  '-n[do not print the final newline]' \
  '(-b -c -w)-p+[specify number of digits after decimal point]:precision:' \
  '(-)1: :_guard "^-*" "number of data"' \
  '2::lower bound:' \
  '3::upper bound:' \
  '4:: :->lastarg' && ret=0

case $state in
  (format)
    local -a flags digits conversions
    flags=(
      '#:alternative form'
      ' :leave a blank before a positive number'
      '+:always place a sign before a number'
      '-:left adjust'
    )
    digits=(0 1 2 3 4 5 6 7 8 9 .)
    conversions=(
      {d,i}':signed decimal'
      'o:unsigned octal'
      'u:unsigned decimal'
      {x,X}':unsigned hexadecimal'
      'l'{d,i}':long signed decimal'
      'lo:long unsigned octal'
      'lu:long unsigned decimal'
      'l'{x,X}':long unsigned hexadecimal'
      'f:double number'
      {e,E}':double number in scientific notation'
      {g,G}':use %f or %e, whichever is more appropriate'
      'c:character'
    )

compset -P '([^%]#%%)#'
    if compset -P '[^%]#%'; then
      # flags: (|\#)(| )(|+|-)
      compset -P '(\#|\\\#)' && flags=( ${(@)flags:#\#*} )
      compset -P '( |\\ )' && flags=( ${(@)flags:#(\#| )*} )
      compset -P '(+|-)' || compset -P '[0-9]##' && flags=()
      # width.precision: [0-9]#(|.[0-9]#)
      if compset -P '.'; then
	flags=()
	digits=( ${(@)digits:#.} )
      fi
      compset -P '[0-9]#'
      # conversion specifier: ((|l)[diouxX]|[feEgGc])
      if compset -P '((|l)[diouxX]|[feEgGc])'; then
	_message -e format-rest 'rest of the format' && ret=0
      else
	local opts=( -S '' )
	_alternative -O opts 'flags:flag:(( $flags ))' \
	    "width-precision:width.precision:($digits)" \
	    'conversion-specifiers:conversion specifier:(( $conversions ))' \
	    && ret=0
      fi
    else
      local expl
      compset -P '*'
      _wanted start-specification expl 'start specification' \
				compadd -S '' % && ret=0
    fi
    ;;
  (lastarg)
    if (( $+opt_args[-r] )); then
      _message -e seeds 'random number seed' && ret=0
    else
      _message -e steps 'step size' && ret=0
    fi
    ;;
esac

return ret

${this.title}

Code Editor : _jot