Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
cmaps	[ DIR ]	drwxr-xr-x
help	[ DIR ]	drwxr-xr-x
rline	[ DIR ]	drwxr-xr-x
scripts	[ DIR ]	drwxr-xr-x
arrayfuns.sl	1.85 KB	-rw-r--r--
autoload.sl	460 B	-rw-r--r--
base64.sl	19 B	-rw-r--r--
chksum.sl	1.58 KB	-rw-r--r--
cmdopt.sl	7.58 KB	-rw-r--r--
csv.sl	16.35 KB	-rw-r--r--
fcntl.sl	35 B	-rw-r--r--
fork.sl	17 B	-rw-r--r--
fswalk.sl	2.36 KB	-rw-r--r--
glob.sl	2.42 KB	-rw-r--r--
histogram.sl	2.98 KB	-rw-r--r--
iconv.sl	35 B	-rw-r--r--
json.sl	5.97 KB	-rw-r--r--
listfuns.sl	3.04 KB	-rw-r--r--
onig.sl	17 B	-rw-r--r--
pcre.sl	1.21 KB	-rw-r--r--
png.sl	4.02 KB	-rw-r--r--
print.sl	7.61 KB	-rw-r--r--
process.sl	9.83 KB	-rw-r--r--
profile.sl	19.88 KB	-rw-r--r--
rand.sl	4.28 KB	-rw-r--r--
readascii.sl	5.24 KB	-rw-r--r--
require.sl	1.27 KB	-rw-r--r--
select.sl	37 B	-rw-r--r--
setfuns.sl	4.8 KB	-rw-r--r--
sldb.sl	2.11 KB	-rw-r--r--
sldbcore.sl	18.1 KB	-rw-r--r--
sldbsock.sl	7.43 KB	-rw-r--r--
slshhelp.sl	536 B	-rw-r--r--
slshrl.sl	9.23 KB	-rw-r--r--
slsmg.sl	35 B	-rw-r--r--
socket.sl	151 B	-rw-r--r--
stats.sl	15.07 KB	-rw-r--r--
stkcheck.sl	2.62 KB	-rw-r--r--
structfuns.sl	2.05 KB	-rw-r--r--
sysconf.sl	20 B	-rw-r--r--
termios.sl	39 B	-rw-r--r--
varray.sl	37 B	-rw-r--r--
zlib.sl	2.93 KB	-rw-r--r--

Code Editor : fswalk.sl

% Functions to walk the file system
% Copyright (C) 2012-2017,2018 John E. Davis
%
% This file is part of the S-Lang Library and may be distributed under the
% terms of the GNU General Public License.  See the file COPYING for
% more information.

private define process_dir (w, dir, dir_st);
private define process_dir (w, dir, dir_st)
{
   variable status;
   if (w.dir_method != NULL)
     {
	status = (@w.dir_method) (dir, dir_st, __push_list (w.dir_method_args));
	if (status <= 0)
	  return status;
     }

foreach (listdir (dir))
     {
	variable file = ();
	file = path_concat (dir, file);
	variable st = (@w.stat_func)(file);
	if (st == NULL)
	  {
	     () = fprintf (stderr, "Unable to stat %s: %s\n", file, errno_string (errno));
	     continue;
	  }
	if (stat_is ("dir", st.st_mode))
	  {
	     status = process_dir (w, file, dir_st);
	     if (status < 0)
	       return status;

continue;
	  }

if (w.file_method == NULL)
	  continue;
	status = (@w.file_method) (file, st, __push_list(w.file_method_args));
	if (status <= 0)
	  return status;
     }
   return 1;
}

private define fswalk (w, start)
{
   variable st = (@w.stat_func)(start);
   ifnot (stat_is ("dir", st.st_mode))
     {
	throw InvalidParmError, "fs_walk: $start is not a directory"$;
     }
   () = process_dir (w, start, st);
}

define fswalk_new ()
{
   if (_NARGS != 2)
     usage ("\
w = fswalk_new (dirfunc, filefunc [; qualifiers]);\n\
w.walk (topdir);\n\
\n\
Qualifiers:\n\
  dargs={args,...}     Additional arguments to be passed to dirfunc\n\
  fargs={args,...}     Additional arguments to be passed to dirfunc\n\
  followlinks[=0|1]    Indicates whethe or not symbolic links will be followed\n\
");

variable dir_method, file_method;
   (dir_method, file_method) = ();

variable dir_method_args = qualifier ("dargs", {});
   variable file_method_args = qualifier ("fargs", {});
   if (typeof (dir_method_args) != List_Type)
     dir_method_args = {dir_method_args};
   if (typeof (file_method_args) != List_Type)
     file_method_args = {file_method_args};
   variable followlinks
     = (qualifier_exists ("followlinks") && (0 != qualifier ("followlinks")));

variable w = struct
     {
	walk = &fswalk,
	file_method = file_method,
	file_method_args = file_method_args,
	dir_method = dir_method,
	dir_method_args = dir_method_args,
	stat_func = (followlinks ? &stat_file : &lstat_file),
     };
   return w;
}

${this.title}

Code Editor : fswalk.sl