Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
MkOrigtargz	[ DIR ]	drwxr-xr-x
Salsa	[ DIR ]	drwxr-xr-x
Uscan	[ DIR ]	drwxr-xr-x
Compression.pm	3.1 KB	-rw-r--r--
Config.pm	10.9 KB	-rw-r--r--
DB_File_Lock.pm	10.79 KB	-rw-r--r--
Debbugs.pm	11.57 KB	-rw-r--r--
JSONCache.pm	1.61 KB	-rw-r--r--
MkOrigtargz.pm	20.68 KB	-rw-r--r--
Output.pm	1.49 KB	-rw-r--r--
PackageDeps.pm	9.14 KB	-rw-r--r--
Packages.pm	8.93 KB	-rw-r--r--
Salsa.pm	9.39 KB	-rw-r--r--
Set.pm	2.87 KB	-rw-r--r--
Utils.pm	482 B	-rw-r--r--
Versort.pm	2.05 KB	-rw-r--r--

Code Editor : JSONCache.pm

package Devscripts::JSONCache;

use strict;
use JSON;
use Moo;

has file => (is => 'rw', required => 1);

has saved => (is => 'rw');

has _data => (is => 'rw');

sub save_sec {
    my ($self, $obj) = @_;
    my $tmp = umask;
    umask 0177;
    open(my $fh, '>', $self->file) or ($self->saved(1) and die $!);
    print $fh JSON::to_json($obj);
    close $fh;
    umask $tmp;
}

sub data {
    my ($self) = @_;
    return $self->_data if $self->_data;
    my $res;
    if (-r $self->file) {
        open(F, $self->file) or ($self->saved(1) and die $!);
        $res = JSON::from_json(join('', <F>) || "{}");
        close F;
    } else {
        $self->save_sec({});
        $self->saved(0);
    }
    return $self->_data($res);
}

sub TIEHASH {
    my $r = shift->new({
        file => shift,
        @_,
    });
    # build data
    $r->data;
    return $r;
}

sub FETCH {
    return $_[0]->data->{ $_[1] };
}

sub STORE {
    $_[0]->data->{ $_[1] } = $_[2];
}

sub DELETE {
    delete $_[0]->data->{ $_[1] };
}

sub CLEAR {
    $_[0]->save({});
}

sub EXISTS {
    return exists $_[0]->data->{ $_[1] };
}

sub FIRSTKEY {
    my ($k) = sort { $a cmp $b } keys %{ $_[0]->data };
    return $k;
}

sub NEXTKEY {
    my ($self, $last) = @_;
    my $i    = 0;
    my @keys = map {
        return $_ if ($i);
        $i++      if ($_ eq $last);
        return ()
      }
      sort { $a cmp $b } keys %{ $_[0]->data };
    return @keys ? $keys[0] : ();
}

sub SCALAR {
    return scalar %{ $_[0]->data };
}

sub save {
    return if ($_[0]->saved);
    eval { $_[0]->save_sec($_[0]->data); };
    $_[0]->saved(1);
}

*DESTROY = *UNTIE = *save;

${this.title}

Code Editor : JSONCache.pm