Gecko [ fernandoquevedodop.com ]

Name	Size	Permission
srfi-171	[ DIR ]	drwxr-xr-x
srfi-4	[ DIR ]	drwxr-xr-x
srfi-42	[ DIR ]	drwxr-xr-x
srfi-64	[ DIR ]	drwxr-xr-x
srfi-67	[ DIR ]	drwxr-xr-x
srfi-9	[ DIR ]	drwxr-xr-x
srfi-1.scm	30.49 KB	-rw-r--r--
srfi-10.scm	2.76 KB	-rw-r--r--
srfi-11.scm	5.38 KB	-rw-r--r--
srfi-111.scm	1.28 KB	-rw-r--r--
srfi-13.scm	2.72 KB	-rw-r--r--
srfi-14.scm	2.33 KB	-rw-r--r--
srfi-16.scm	1.84 KB	-rw-r--r--
srfi-17.scm	6.42 KB	-rw-r--r--
srfi-171.scm	13.16 KB	-rw-r--r--
srfi-18.scm	12.12 KB	-rw-r--r--
srfi-19.scm	54.91 KB	-rw-r--r--
srfi-2.scm	1.08 KB	-rw-r--r--
srfi-26.scm	2.58 KB	-rw-r--r--
srfi-27.scm	2.98 KB	-rw-r--r--
srfi-28.scm	1.17 KB	-rw-r--r--
srfi-31.scm	1.36 KB	-rw-r--r--
srfi-34.scm	1.41 KB	-rw-r--r--
srfi-35.scm	5.85 KB	-rw-r--r--
srfi-37.scm	8.39 KB	-rw-r--r--
srfi-38.scm	8.19 KB	-rw-r--r--
srfi-39.scm	2.11 KB	-rw-r--r--
srfi-4.scm	4.99 KB	-rw-r--r--
srfi-41.scm	19.91 KB	-rw-r--r--
srfi-42.scm	1.75 KB	-rw-r--r--
srfi-43.scm	38.26 KB	-rw-r--r--
srfi-45.scm	3.5 KB	-rw-r--r--
srfi-6.scm	1.07 KB	-rw-r--r--
srfi-60.scm	2.13 KB	-rw-r--r--
srfi-64.scm	2.56 KB	-rw-r--r--
srfi-67.scm	2.31 KB	-rw-r--r--
srfi-69.scm	12.7 KB	-rw-r--r--
srfi-71.scm	10.08 KB	-rw-r--r--
srfi-8.scm	1.08 KB	-rw-r--r--
srfi-88.scm	1.71 KB	-rw-r--r--
srfi-9.scm	13.05 KB	-rw-r--r--
srfi-98.scm	1.57 KB	-rw-r--r--

Code Editor : srfi-35.scm

;;; srfi-35.scm --- Conditions                 -*- coding: utf-8 -*-

;; Copyright (C) 2007-2011, 2017 Free Software Foundation, Inc.
;;
;; This library is free software; you can redistribute it and/or
;; modify it under the terms of the GNU Lesser General Public
;; License as published by the Free Software Foundation; either
;; version 3 of the License, or (at your option) any later version.
;;
;; This library is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; Lesser General Public License for more details.
;;
;; You should have received a copy of the GNU Lesser General Public
;; License along with this library; if not, write to the Free Software
;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA

;;; Author: Ludovic Courtès <ludo@gnu.org>

;;; Commentary:

;; This is an implementation of SRFI-35, "Conditions".  Conditions are a
;; means to convey information about exceptional conditions between parts of
;; a program.

;;; Code:

(define-module (srfi srfi-35)
  #:use-module (ice-9 match)
  #:use-module (ice-9 exceptions)
  #:re-export ((make-exception-type . make-condition-type)
               (exception-type? . condition-type?)
               (exception? . condition?)
               (make-exception . make-compound-condition)
               (&exception . &condition)
               &message
               (exception-with-message? . message-condition?)
               (exception-message . condition-message)
               (&error . &serious)
               (error? . serious-condition?)
               (external-error? . error?))
  #:re-export-and-replace ((&external-error . &error))
  #:export (make-condition
            define-condition-type
            condition-has-type?
            condition-ref
            extract-condition
            condition))

(cond-expand-provide (current-module) '(srfi-35))

(define (make-condition type . field+value)
  "Return a new condition of type TYPE with fields initialized as specified
by FIELD+VALUE, a sequence of field names (symbols) and values."
  (unless (exception-type? type)
    (scm-error 'wrong-type-arg "make-condition" "Not a condition type: ~S"
               (list type) #f))
  (let* ((fields (record-type-fields type))
         (uninitialized (list 'uninitialized))
         (inits (make-vector (length fields) uninitialized)))
    (let lp ((args field+value))
      (match args
        (()
         (let lp ((i 0) (fields fields))
           (when (< i (vector-length inits))
             (when (eq? (vector-ref inits i) uninitialized)
               (error "field not specified" (car fields)))
             (lp (1+ i) (cdr fields))))
         (apply make-struct/simple type (vector->list inits)))
        (((and (? symbol?) field) value . args)
         (let lp ((i 0) (fields fields))
           (when (null? fields)
             (error "unknown field" field))
           (cond
            ((eq? field (car fields))
             (unless (eq? (vector-ref inits i) uninitialized)
               (error "duplicate initializer" field))
             (vector-set! inits i value))
            (else
             (lp (1+ i) (cdr fields)))))
         (lp args))
        (inits
         (scm-error 'wrong-type-arg "make-condition"
                    "Bad initializer list tail: ~S"
                    (list inits) #f))))))

(define (condition-has-type? c type)
  "Return true if condition C has type TYPE."
  (unless (exception-type? type)
    (scm-error 'wrong-type-arg "condition-has-type?" "Not a condition type: ~S"
               (list type) #f))
  (or-map (record-predicate type) (simple-exceptions c)))

;; Precondition: C is a simple condition.
(define (simple-condition-ref c field-name not-found)
  (match (list-index (record-type-fields (struct-vtable c)) field-name)
    (#f (not-found))
    (pos (struct-ref c pos))))

(define (condition-ref c field-name)
  "Return the value of the field named FIELD-NAME from condition C."
  (let lp ((conditions (simple-exceptions c)))
    (match conditions
      (() (error "invalid field name" field-name))
      ((c . conditions)
       (simple-condition-ref c field-name (lambda () (lp conditions)))))))

(define (make-condition-from-values type values)
  (apply make-struct/simple type values))

(define (extract-condition c type)
  "Return a condition of condition type TYPE with the field values specified
by C."
  (unless (exception-type? type)
    (scm-error 'wrong-type-arg "extract-condition" "Not a condition type: ~S"
               (list type) #f))
  (let ((pred (record-predicate type)))
    (or-map (lambda (x) (and (pred x) x)) (simple-exceptions c))))

(define-syntax define-condition-type
  (lambda (s)
    (syntax-case s ()
      ((_ type parent predicate (field accessor) ...)
       ;; The constructor is unused, but generate a new name for each
       ;; condition to avoid '-Wshadowed-toplevel' warnings when several
       ;; condition types are defined in the same compilation unit.
       (with-syntax ((unused-constructor
                      (datum->syntax
                       #'type
                       (symbol-append '#{ make-}# (syntax->datum #'type)))))
         #'(define-exception-type type parent
             unused-constructor predicate
             (field accessor) ...))))))

(define-syntax condition-instantiation
  ;; Build the `(make-condition type ...)' call.
  (syntax-rules ()
    ((_ type (out ...))
     (make-condition type out ...))
    ((_ type (out ...) (field-name field-value) rest ...)
     (condition-instantiation type (out ... 'field-name field-value) rest ...))))

(define-syntax condition
  (syntax-rules ()
    ((_ (type field ...))
     (condition-instantiation type () field ...))
    ((_ (type field ...) ...)
     (make-compound-condition (condition-instantiation type () field ...)
                              ...))))

${this.title}

Code Editor : srfi-35.scm